apply plugin: 'com.android.application'
apply plugin: 'io.fabric'

def gitCommit = 'git rev-parse --short HEAD'.execute([], project.rootDir).text.trim()

android {
    compileSdkVersion 29
    buildToolsVersion "29.0.2"
    defaultConfig {
        applicationId "org.itxtech.daedalus"
        minSdkVersion 21
        targetSdkVersion 29
        versionCode 20
        versionName "1.14.1"

        buildConfigField "String", "BUILD_TIME", "\"${System.currentTimeMillis()}\""
        buildConfigField "String", "GIT_COMMIT", "\"${gitCommit}\""
    }
    buildTypes {
        release {
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    flavorDimensions "default"
    productFlavors {
        pure {
            dimension "default"
        }
        google {
            dimension "default"
        }
    }
    lintOptions {
        checkReleaseBuilds false
        abortOnError false
    }
    applicationVariants.all { variant ->
        variant.outputs.all {
            outputFileName = outputFileName.replace("app", "${defaultConfig.applicationId}_${defaultConfig.versionName}_${gitCommit}")
        }
    }
    compileOptions {
        sourceCompatibility JavaVersion.VERSION_1_8
        targetCompatibility JavaVersion.VERSION_1_8
    }
}

configurations {
    googleReleaseImplementation
}

dependencies {
    //Support
    implementation 'androidx.appcompat:appcompat:1.1.0'
    implementation 'androidx.legacy:legacy-support-v4:1.0.0'
    implementation 'androidx.percentlayout:percentlayout:1.0.0'
    implementation 'androidx.cardview:cardview:1.0.0'
    implementation 'com.google.android.material:material:1.1.0-alpha10'
    implementation 'androidx.recyclerview:recyclerview:1.1.0-beta04'
    //DNS
    implementation 'org.pcap4j:pcap4j-core:1.7.6'
    implementation 'org.pcap4j:pcap4j-packetfactory-static:1.7.6'
    implementation 'org.minidns:minidns-client:0.3.4'
    implementation 'com.google.code.gson:gson:2.8.5'
    implementation 'com.squareup.okhttp3:okhttp:3.14.1'

    //Analytics
    googleReleaseImplementation 'com.google.firebase:firebase-core:17.2.0'
    googleReleaseImplementation 'com.crashlytics.sdk.android:crashlytics:2.10.1'
}

apply plugin: 'com.google.gms.google-services'

android.applicationVariants.all { variant ->
    project.tasks.each { t ->
        if (!t.name.toLowerCase().contains("googlerelease") &&
                (t.name.contains("GoogleServices") || t.name.contains("fabric"))) {
            t.enabled = false
        }
    }
}